Les expressions dans le serveur HTTP Apache

Syntaxe en Forme de Backus-Naur

La Forme de Backus-Naur (souvent abr�g�e en BNF, de l'anglais Backus-Naur Form) est une notation permettant de d�crire les r�gles syntaxiques des langages de programmation. En g�n�ral, les expressions repr�sentent des valeurs bool�ennes. Dans ce cas, le point de d�part de la BNF est expr. Cependant, certaines directives comme LogMessage utilisent comme param�tres des expressions qui repr�sentent des cha�nes de caract�res. Dans ce cas, le point de d�part de la BNF est string.

expr        ::= "true" | "false"
              | "!" expr
              | expr "&&" expr
              | expr "||" expr
              | "(" expr ")"
              | comp

comp        ::= stringcomp
              | integercomp
              | unaryop word
              | word binaryop word
              | word "in" "{" wordlist "}"
              | word "in" listfunction
              | word "=~" regex
              | word "!~" regex


stringcomp  ::= word "==" word
              | word "!=" word
              | word "<"  word
              | word "<=" word
              | word ">"  word
              | word ">=" word

integercomp ::= word "-eq" word | word "eq" word
              | word "-ne" word | word "ne" word
              | word "-lt" word | word "lt" word
              | word "-le" word | word "le" word
              | word "-gt" word | word "gt" word
              | word "-ge" word | word "ge" word

wordlist    ::= word
              | wordlist "," word

word        ::= word "." word
              | digit
              | "'" string "'"
              | """ string """
              | variable
	      | rebackref
              | function

string      ::= stringpart
              | string stringpart

stringpart  ::= cstring
              | variable
	      | rebackref

cstring     ::= ...
digit       ::= [0-9]+

variable    ::= "%{" varname "}"
              | "%{" funcname ":" funcargs "}"

rebackref   ::= "$" [0-9]

function     ::= funcname "(" word ")"

listfunction ::= listfuncname "(" word ")"

Variables

L'interpr�teur d'expressions fournit plusieurs variables de la forme %{HTTP_HOST}. Notez que la valeur d'une variable peut d�pendre de la phase du traitement de la requ�te au cours de laquelle elle est �valu�e. Par exemple, une expression utilis�e dans une directive <If > sera �valu�e avant la phase d'authentification. Par cons�quent, la variable %{REMOTE_USER} ne sera pas encore d�finie � ce stade.

Les variables suivantes contiennent la valeur de l'en-t�te de requ�te HTTP correspondant. La fonction req permet d'extraire les valeurs des autres en-t�tes. L'utilisation de ces variables peut provoquer l'ajout du nom d'en-t�te correspondant � l'en-t�te Vary de la r�ponse HTTP, sauf sp�cification contraire pour la directive qui accepte l'expression comme param�tre. La function req_novary permet de modifier ce comportement.

Autres variables li�es aux requ�tes

Variables diverses

Certains modules, comme mod_ssl, d�finissent des variables suppl�mentaires.

Op�rateurs binaires

� l'exception de quelques op�rateurs de comparaison internes, les op�rateurs binaires sont de la forme "-[a-zA-Z][a-zA-Z0-9_]+", autrement dit un signe moins et au moins deux caract�res. Le nom est insensible � la casse. Les modules peuvent fournir des op�rateurs binaires suppl�mentaires.

Op�rateurs de comparaison

Autres op�rateurs binaires

Op�rateurs unaires

Les op�rateurs unaires acceptent un seul argument et sont de la forme "-[a-zA-Z]", autrement dit le signe moins et un caract�re. Le nom est sensible � la casse. Les modules peuvent fournir des op�rateurs unaires suppl�mentaires.

Les op�rateurs marqu�s comme "restreints" ne sont pas disponibles avec certains modules comme mod_include.

Fonctions

Normalement, les fonctions dont la valeur est une cha�ne acceptent une cha�ne comme argument et renvoient une cha�ne. Les noms de fonctions sont insensibles � la casse. Les modules peuvent fournir des fonctions suppl�mentaires.

Les fonctions marqu�es comme "restreints" ne sont pas disponibles avec certains modules comme mod_include.

Lorsque les fonctions req ou http sont utilis�es, le nom d'en-t�te sera automatiquement ajout� � l'en-t�te Vary de la r�ponse HTTP, sauf sp�cification contraire pour la directive qui accepte l'expression comme param�tre. La fonction req_novary permet d'emp�cher l'ajout de noms d'en-t�tes � l'en-t�te Vary.

En plus des fonctions dont la valeur est une cha�ne, il existe aussi des fonctions dont la valeur est une liste, qui acceptent une cha�ne comme argument, et renvoient une liste de mots, autrement dit une liste de cha�nes. La liste de mot peut �tre utilis�e avec l'op�rateur sp�cial -in. Les noms de fonctions sont insensibles � la casse. Les modules peuvent fournir des fonctions suppl�mentaires.

Il n'existe pas de fonctions internes dont la valeur est une liste. Le module mod_ssl fournit la fonction PeerExtList. Voir la description de la directive SSLRequire pour plus de d�tails (notez que la fonction PeerExtList peut aussi �tre utilis�e en dehors de la directive SSLRequire).

Exemples d'expressions

Les exemples suivants montent comment utiliser les expressions pour �valuer les requ�tes :

# Comparer le nom d'h�te avec example.com et rediriger vers
# www.example.com si le nom d'h�te correspond
<If "%{HTTP_HOST} == 'example.com'">
    Redirect permanent / http://www.example.com/
</If>

# Forcer le type text/plain si un fichier fait l'objet d'une
# requ�te dont la cha�ne de param�tres contient 'forcetext'
<If "%{QUERY_STRING} =~ /forcetext/">
    ForceType text/plain
</If>

# N'autoriser l'acc�s � ce contenu que pendant les heures de
# travail
<Directory "/foo/bar/business">
     Require expr %{TIME_HOUR} -gt 9 && %{TIME_HOUR} -lt 17
</Directory>

Autres

R�f�rences arri�res dans les expressions rationnelles

Les cha�nes $0 ... $9 permettent de r�f�rencer les groupes de capture en provenance d'expressions rationnelles pr�c�demment ex�cut�es et mises en correspondance avec succ�s. Elles ne peuvent normalement �tre utilis�es que dans la m�me expression que celle mise en correspondance, mais certains modules permettent de les utiliser de mani�re sp�ciale.

Comparaison avec SSLRequire

La syntaxe ap_expr consiste principalement en une surcouche de la syntaxe de la directive obsol�te SSLRequire. Vous pouvez consulter la liste de leur diff�rences dans la documentation de la directive SSLRequire.

Historique de version

La fonction req_novary est disponible � partir de la version 2.4.4 du serveur HTTP Apache.